VBAでNotesカレンダーを取得する簡単なサンプル

はじめに

今となっては少し下火になっている(?)そんなNotesですが、グループウェアの先駆けとして使用している組織も多いことと思います。

そんなNotesですが、こちらの記事では、JavaでNotesのカレンダーを取得する方法を紹介しましたが、VBAでもNotesを操作することができます。

この記事ではVBAによるNotesカレンダーの取得について紹介していこうと思います。

Notesのカレンダーとは

Notesにはカレンダー機能がありスケジュール帳として使われたり、組織のスケジュール共有に使われたりしています。

Notesのカレンダー機能はなかなか使い勝手がよく、Googleカレンダーにも引けを取らないと個人的に思っています。(個人の感想です)

VBAでNotesカレンダーを取得する

VBAでNotesカレンダーを取得するコードを書くときは、参照設定で「Lotus Domino Object」のチェックしておくと、インテリセンスのおかげで少し楽をすることができます。

Notesカレンダーを取得する例は次のようになりますが、環境に合わせて定数を設定する必要があります。何を設定すればいいかわからない場合は、下記の記事をご覧ください。

VBAでNotesメールを作成・送信する_最も簡単なサンプル - 適材適所

 

Sub printNotesCalendarList()
    Const PASSWORD As String = "環境に合わせて設定"
    Const SERVER As String = "環境に合わせて設定"
    Const NOTES_FILE As String = "環境に合わせて設定.nsf"
    'セッションを確立
    Dim notesSession As notesSession: Set notesSession = New notesSession
    notesSession.Initialize PASSWORD
    'Notesのデータベースを取得
    Dim notesDB As NotesDatabase: Set notesDB = notesSession.GetDatabase(SERVER, NOTES_FILE)
    'カレンダーViewの取得
    Dim view As NotesView: Set view = notesDB.GetView("$Calendar")
    
    'カレンダーの最初の文書を取得
    Dim notesDoc As NotesDocument: Set notesDoc = view.GetFirstDocument
    
    '全てのカレンダーにアクセスする
    Do Until (notesDoc Is Nothing)
        Dim subject As String: subject = notesDoc.GetItemValue("Subject")(0)
        Dim body As String: body = notesDoc.GetItemValue("Body")(0)
        '開始日時と終了日時のスマートな処理方法がわからず、無理やり処理しています。
        On Error Resume Next
        Dim startDateTime As Date: startDateTime = notesDoc.GetItemValue("StartDateTime")(0)
        If Err.Description <> "" Then
            startDateTime = notesDoc.GetItemValue("StartDate")(0)
        End If
        Err.Clear
        Dim endDateTime As Date: endDateTime = notesDoc.GetItemValue("EndDateTime")(0)
        If Err.Description <> "" Then
            endDateTime = notesDoc.GetItemValue("EndDate")(0)
        End If
        On Error GoTo 0
        Dim location As String: location = notesDoc.GetItemValue("Location")(0)
        Dim form As String: form = notesDoc.GetItemValue("Form")(0)
        Debug.Print "タイトル：" & subject
        Debug.Print "内容：" & body
        Debug.Print "開始日:" & startDateTime
        Debug.Print "終了日:" & endDateTime
        Debug.Print "場所:" & location
        Debug.Print "タイプ:" & form
        Debug.Print "---------------------------------"
        '次の文書を取得する
        Set notesDoc = view.GetNextDocument(notesDoc)
    Loop
    
End Sub

ひとこと

ポイントは、NotesDatabaseから、カレンダーのビューを指定して取得しているところです。

 Dim view As NotesView: Set view = notesDB.GetView("$Calendar")

その上で、カレンダービュー内の全てのドキュメント、つまり１つ１つの予定にアクセスしています。

次のコードで最初のドキュメントを取得し、あとは、ドキュメントがなくなるまでカレンダービュー内の全てのドキュメントにアクセスしています。

Dim notesDoc As NotesDocument: Set notesDoc = view.GetFirstDocument

終わりに

これを応用すれば、VBAを使ってGoogleカレンダーなどの他のカレンダーアプリケーションと同期するプログラムを書く、なんてことも可能になります。

COMオブジェクトを備えたNotesは外部から操作する敷居が低いため、うまく使いこなすことができれば、他のグループウェアよりも簡単にRPAソフト無しで、大体のことができるというメリットがあります。

そんなヒントを他のNotes関連の記事でも紹介しておりますので、よかったらご参照頂けますと幸いです。

というわけで、ここまでお読みいただき、ありがとうございました。